#!/bin/sh
# Tcl ignores the next line -*- tcl -*- \
exec wish "$0" -- "$@"

######################################################
#        Tcl/Tk Project manager 2.0
#        Distributed under GNU Public License
# Author: Sergey Kalinin svk@nuk-svl.ru
# Home page: https://nuk-svk.ru
######################################################
# Version: 2.0.0
# Release: alpha
######################################################

# определим текущую версию и релиз
set f [open [info script] "RDONLY"]
while {[gets $f line] >=0} {
    if [regexp -nocase -all -- {version:\s+([0-9]+?.[0-9]+?.[0-9]+?)} $line match v1] {
        

        set projmanVersion $v1
    }
    if [regexp -nocase -all -- {release:\s+([a-z0-9]+?)} $line match v1] {
        set projmanRelease $v1
    }
}
close $f

puts "Projman version $projmanVersion-$projmanRelease"


if { $::argc > 0 } {
    foreach arg $::argv {
        lappend opened $arg
    }
    puts $opened
}
package require msgcat
package require inifile
package require ctext

# Устанавливаем текущий каталог
set dir(root) [pwd]

set dir(doc) [file join $dir(root) doc]

# Устанавливаем рабочий каталог, если его нет то создаём.
# Согласно спецификации XDG проверяем наличие переменных и каталогов
if [info exists env(XDG_CONFIG_HOME)] {
    set dir(cfg) [file join $env(XDG_CONFIG_HOME) projman]
} elseif [file exists [file join $env(HOME) .config]] {
    set dir(cfg) [file join $env(HOME) .config projman]
} else {
    set dir(cfg) [file join $env(HOME) .projman]
}

if {[file exists $dir(cfg)] == 0} {
    file mkdir $dir(cfg)    
}

puts "Config dir is $dir(cfg)"

# каталог с модулями
set dir(lib) "[file join $dir(root) lib]"

source [file join $dir(lib) config.tcl]

foreach modFile [lsort [glob -nocomplain [file join $dir(lib) *.tcl]]] {
    if {[file tail $modFile] ne "gui.tcl" && [file tail $modFile] ne "config.tcl"} {
        source $modFile
        puts "Loading module $modFile"
    }
}

# TTK Theme loading
set dir(theme) "[file join $dir(root) theme]"
foreach modFile [lsort [glob -nocomplain [file join $dir(theme) *]]] {
    if [file isdirectory $modFile] {
        source $modFile/[file tail $modFile].tcl
        puts "Loading theme $modFile.tcl"
    } elseif {[file extension $modFile] eq ".tcl"} {
        source $modFile
        puts "Loading theme $modFile"
    }
}


# загружаем пользовательский конфиг, если он отсутствует, то копируем дефолтный
if {[file exists [file join $dir(cfg) projman.ini]] ==0} {
    Config::create $dir(cfg)
} 
Config::read $dir(cfg)

::msgcat::mclocale $cfgVariables(locale)

if [::msgcat::mcload [file join $dir(lib) msgs]] {
    puts "Load locale messages... OK"
}
puts "Setting the locale... [::msgcat::mclocale]"

source [file join $dir(lib) gui.tcl]

# Open the PATH if command line argument has been setting
if [info exists opened] {
    puts $opened
    foreach path $opened {
        if [file isdirectory $path] {
            FileOper::ReadFolder $path
        } elseif [file exists $path] {
            ResetModifiedFlag [FileOper::Edit $path]
        }
    }
}
