Исправил перевод (все равно какой-то кривой)

Reviewed-on: #10

README.md

@@ -17,6 +17,7 @@ Highlightning and source code navigation:
 * Markdown
 * YAML (Ansible support)
 * Lua
+* C
 
 Highlightning:
 

debian/changelog

@@ -1,3 +1,24 @@
+projman (2.0.0-beta5) stable; urgency=medium
+
+  *  Добавил код из https://github.com/wandrien/projman/tree/master для работы с выделенным текстом. И внес изменения в связи с этим.
+  *  Исправления работы с С
+
+ -- Sergey Kalinin <svk@nuk-svk.ru>  Fri, 13 Feb 2026 11:27:41 +0300
+
+projman (2.0.0-beta4) stable; urgency=medium
+
+  *  Исправлено регулярное выражение для поиска переменных в коде на С.
+  *  Добавил экранирование '*' в имени функции для поиска.
+  *  Подкрректировал регулярки для работы с С.
+  *  Исиправил закрытие вкладки при отпускании кнопки мыши при нажатии на крестик.
+  *  Добавил иконки для 'c' и 'h'. Добавил сочитание Alt-R в русской раскладке
+  *  Добавил поддержку С подсветка
+  *  Добавил копирование готовых пакетов
+  *  Откорректировал сборку рпм
+  *  Добавил сборку rpm. Исправил changelog-и
+
+ -- svk <svk@nuk-svk.ru>  Fri,  6 Feb 2026 14:07:53 +0300
+
 projman (2.0.0-beta3) stable; urgency=medium
 
   *  changelog-gen: сделал вывод изменения в формате rpm.spec
@@ -497,3 +518,4 @@ projman (2.0.0-alfa0) stable; urgency=medium
 
 
 
+

lib/editor.tcl

@@ -681,7 +681,7 @@ namespace eval Editor {
         bind $txt <Control-Cyrillic_em> "Editor::SelectionPaste $txt"
         bind $txt <Control-l> "SearchVariable $txt; break"
         bind $txt <Control-Cyrillic_de> "SearchVariable $txt; break"
-        bind $txt <Control-i> "ImageBase64Encode $txt"
+        bind $txt <Control-i> "ImageBase64Encode"
         bind $txt <Control-Cyrillic_sha> "ImageBase64Encode $txt"
         bind $txt <Control-bracketleft> "Editor::InsertTabular $txt"
         bind $txt <Control-bracketright> "Editor::DeleteTabular $txt"
@@ -702,6 +702,7 @@ namespace eval Editor {
         bind $txt <Alt-odiaeresis>  "$txt delete {insert wordstart} {insert wordend}"
         bind $txt <Alt-Cyrillic_tse> "$txt delete {insert wordstart} {insert wordend}"
         bind $txt <Alt-r>           "$txt delete {insert linestart} {insert lineend + 1char}"
+        bind $txt <Alt-Cyrillic_ka> "$txt delete {insert linestart} {insert lineend + 1char}"
         bind $txt <Alt-ecircumflex> "$txt delete {insert linestart} {insert lineend + 1char}"
         bind $txt <Alt-Cyrillic_er> "$txt delete {insert linestart} {insert lineend + 1char}"
         bind $txt <Alt-b> "$txt delete {insert linestart} insert"
@@ -745,6 +746,18 @@ namespace eval Editor {
         }
         bind $txt <Control-r> "Editor::SplitEditorForExecute $w $fileType $nb "
         bind $txt <Control-Cyrillic_ka> "Editor::SplitEditorForExecute $w $fileType $nb "
+
+        bind $txt <Control-Shift-U> {SelectionToUpperCase %W}
+        bind $txt <Control-Shift-u> {SelectionToUpperCase %W}
+        bind $txt <Control-Shift-L> {SelectionToLowerCase %W}
+        bind $txt <Control-Shift-l> {SelectionToLowerCase %W}
+        bind $txt <Control-Shift-T> {SelectionToTitleCase %W}
+        bind $txt <Control-Shift-t> {SelectionToTitleCase %W}
+        bind $txt <Control-Shift-Y> {SelectionToSentenceCase %W}
+        bind $txt <Control-Shift-y> {SelectionToSentenceCase %W}
+        bind $txt <Control-Shift-I> {SelectionToggleCase %W}
+        bind $txt <Control-Shift-i> {SelectionToggleCase %W}
+
         # bind $txt <Shift-Control-s> FileOper::Close
         # bind $txt <Shift-Control-Cyrillic_es> "FileOper::Close saveas"
 
@@ -876,9 +889,15 @@ namespace eval Editor {
         for {set lineNumber 0} {$lineNumber <= [$txt count -lines 0.0 end]} {incr lineNumber} {
             set line [$txt get $lineNumber.0 $lineNumber.end]
             # Выбираем процедуры (функции, классы и т.д.)
+            # DebugPuts "Editor::RedaStructure: file type $fileType"
+            
             if {[dict exists $lexers $fileType procRegexpCommand] != 0 } {
+                # regexp -nocase -all -line -- {^\s*(?:(\w+)\s+)+(\w+)\s*\((.*?)\)\s*(?:;|\{)} $line match returns procName params
+                # regexp -nocase -all -line -lineanchor -linestop -- {^\s*(?:(\w+)\s+)+(\w+)\s*\((.*?)(,|\))} $line match v1 v2 v3 v4
                 if {[eval [dict get $lexers $fileType procRegexpCommand]]} {
+                    DebugPuts "Editor::RedaStructure: regexp = [dict get $lexers $fileType procRegexpCommand]"
                     set procName_ [string trim $procName]
+                    DebugPuts "Editor::RedaStructure: find the proc $procName_"
                     if {$treeItemName ne ""} {
                         Tree::InsertItem $tree $treeItemName $procName_  "procedure" "$procName_ ($params)"
                     }

lib/gui.tcl

@@ -236,8 +236,8 @@ ttk::style layout TNotebook.Tab {
     }
 }
 bind TNotebook <Button-1> "catch {NB::PressTab %W %x %y}\;[bind TNotebook <Button-1>];break"
-# bind <<NotebookTabChanged>> "NB::PressTab %W %x %y"
-bind TNotebook <ButtonRelease-1> "NB::PressTab %W %x %y"
+bind <<NotebookTabChanged>> "catch {NB::PressTab %W %x %y}\;[bind TNotebook <Button-1>];break"
+# bind TNotebook <ButtonRelease-1> "NB::PressTab %W %x %y"
 # bind TNotebook <Control-w> FileOper::Close
 # bind . <Control-Tab> "NB::NextTab $nbEditor"
 bind . <Control-Next> "NB::NextTab $nbEditor 1"

lib/highlight.tcl

@@ -210,5 +210,24 @@ namespace eval Highlight {} {
         ctext::addHighlightClass $txt compile_errors #ff5050 {error Error ERROR invalid undefined cannot}
         ctext::addHighlightClassForRegexp $txt url lightblue {\w+://\w.+\w+}
     }
-
+    proc C {txt} {
+        global lexers
+        ctext::addHighlightClassForRegexp $txt flags orange {-+[a-zA-Z\-_]+}
+        ctext::addHighlightClassForRegexp $txt arrows orange {(->)|(-<)}
+        ctext::addHighlightClass $txt stackControl #19a2a6 [dict get $lexers C commands]
+        ctext::addHighlightClass $txt types #7187d5 {string int int16 int32 int64 float bool byte size_t void char uint32_t uint32}
+        ctext::addHighlightClassWithOnlyCharStart $txt vars #4471ca "\&"
+        ctext::addHighlightClassWithOnlyCharStart $txt vars #4471ca "\*"
+        # ctext::addHighlightClassForRegexp $txt vars_extended #4471ca {\$\{[a-zA-Z0-9\_\-:\./\$\{\}]+\}}
+        ctext::addHighlightClass $txt variable_funcs gold {var type struct}
+        ctext::addHighlightClassForSpecialChars $txt brackets green {[]{}()}
+        ctext::addHighlightClassForRegexp $txt paths lightblue {\.[a-zA-Z0-9\_\-]+}
+        ctext::addHighlightClassForRegexp $txt comments #666666 {(//|/\*)[^\n\r]*}    
+        ctext::addHighlightClassForSpecialChars $txt qoute #b84a0c {"'`}
+        ctext::addHighlightClass $txt bool #3e803b {nil false true NULL TRUE FALSE}
+        ctext::addHighlightClassForRegexp $txt qoute #b84a0c {("|'|`).*?("|'|`)}
+        ctext::addHighlightClassForRegexp $txt macros #f88ffb {#\w+}
+        ctext::addHighlightClassForRegexp $txt include #68ceff {<[\w./_-]+?>}
+    }
+    proc H {txt} {Highlight::C $txt}
 }

lib/image_library.tcl

@@ -1947,3 +1947,24 @@ image create photo settings_24x24 -data {
     3W5MPksIPgdckHTF1XAMeCrpRXAexPT6yYSddEj6eKSJJmk3IcFGqWby51AbSvpeqr+KPjcKC7GT
     hfgXbteIc85F7RUAAAAASUVORK5CYII=
 }
+image create photo c_16x12 -data {
+    iVBORw0KGgoAAAANSUhEUgAAAAsAAAANCAYAAAB/9ZQ7AAAAAXNSR0IB2cksfwAAAARnQU1BAACx
+    jwv8YQUAAAAgY0hSTQAAeiYAAICEAAD6AAAAgOgAAHUwAADqYAAAOpgAABdwnLpRPAAAAAZiS0dE
+    APgAjwD7QQHXygAAAAlwSFlzAAALEwAACxMBAJqcGAAAAAd0SU1FB+oCBg8YOxzsqLgAAABWSURB
+    VCjPY2AgATDCGFeLi/+jS2r39jJiKIYp1O7tZUDSjKGBCYdtyCbCbWTB5T6oiShOYyHWT7icgRPg
+    VHy1uPg/eggRY/J/YsMZRR0jLlNweZI2AAAzbhnP2WkKCAAAAABJRU5ErkJggg==
+}
+image create photo h_16x12 -data {
+    iVBORw0KGgoAAAANSUhEUgAAAAsAAAANCAYAAAB/9ZQ7AAAAAXNSR0IB2cksfwAAAARnQU1BAACx
+    jwv8YQUAAAAgY0hSTQAAeiYAAICEAAD6AAAAgOgAAHUwAADqYAAAOpgAABdwnLpRPAAAAAZiS0dE
+    AAAAAAAA+UO7fwAAAAlwSFlzAAALEwAACxMBAJqcGAAAAAd0SU1FB+oCBg8iNd79W8YAAABJSURB
+    VCjPY2AgB1wtLv5/tbj4Pz41TKQYSJJiRmRnYFOg3dvLSLTJyIawYDEJWSGM+Z+BgYGRCY/zGOkX
+    GkwMFID/UExIjDAAAEu2FECKwea9AAAAAElFTkSuQmCC
+}
+image create photo cpp_16x12 -data {
+    iVBORw0KGgoAAAANSUhEUgAAAAsAAAANCAMAAABIK2QJAAAAAXNSR0IB2cksfwAAAARnQU1BAACx
+    jwv8YQUAAAAgY0hSTQAAeiYAAICEAAD6AAAAgOgAAHUwAADqYAAAOpgAABdwnLpRPAAAAA9QTFRF
+    AAAAzAAAAAAA////////6rs+vwAAAAF0Uk5TAEDm2GYAAAABYktHRACIBR1IAAAACXBIWXMAAAsT
+    AAALEwEAmpwYAAAAB3RJTUUH6gIGDxU21/OqSAAAADVJREFUCNd9jUEOACAIw7D7/58VmNF4sAco
+    CbCIm5FsBTwsd+kmgVQu87p3OLfg/9AJJPFhAjDkAJmwKBolAAAAAElFTkSuQmCC
+}

lib/lexers.tcl

@@ -104,5 +104,29 @@ dict set lexers LUA procFindString {function\s*?PROCNAME}
 dict set lexers LUA procRegexpCommand {regexp -nocase -all -- {^(local|)\s*?(function)\s([a-zA-Z0-9\-_:]+?)\s+\((.+?)\)} $line match v1 keyWord procName params}
 dict set lexers LUA varRegexpCommand {regexp -nocase -all -- {^(\s*?)([a-zA-Z0-9\-_\.]+)\s+=\s+(.+?)(\s*$|--)} $line match indent varName varValue lineEnd}
 
+#--------------------------------------------------
+# C
+dict set lexers C commentSymbol {//}
+dict set lexers C commentMultilineSymbolBegin {/*}
+dict set lexers C commentMultilineSymbolEnd {*/}
+dict set lexers C procFindString {(\w+)\s+(PROCNAME)\s*\((.*?)(,|\))(\W|$)}
+dict set lexers C procRegexpCommand {regexp -nocase -all -line -- {^(?:(\w+)\s+)+(\*\w+|\w+)\s*\((.*?)(,|\))} $line match returns procName params v4}
+# dict set lexers C procRegexpCommand {regexp -nocase -all -- {\s*?func\s*?(\(\w+\s*?\**?\w+\)|)\s*?(\w+)\((.*?)\)\s+?([a-zA-Z0-9\{\}\[\]\(\)-_.]*?|)\s*?\{} $line match linkName procName params returns}
+# dict set lexers C varRegexpCommand {regexp -nocase -all -line -- {^\s*?var\s+([a-zA-Z0-9\-_$]+)\s+(.+?)(\s*$)} $line match varName varType lineEnd}
+dict set lexers C varRegexpCommand {regexp -nocase -all -line -- {^\s*(\w+\s+)+(?:[*\s]+)?(\w+)\s*[=;,\[]} $line match varType varName}
+dict set lexers C commands {auto break case const continue default do else enum extern for goto if inline  int long register restrict return signed sizeof static struct switch typedef typeof typeof_unqual union unsigned void volatile while}
+
+#--------------------------------------------------
+# H
+dict set lexers H commentSymbol {//}
+dict set lexers H commentMultilineSymbolBegin {/*}
+dict set lexers H commentMultilineSymbolEnd {*/}
+# dict set lexers C procFindString {^\s*(?:(\w+)\s+)+(PROCNAME)\s*\((.*?)(,|\))}
+dict set lexers H procFindString {^\s*(?:(\w+)\s+)+(PROCNAME)\s*\((.*?)(,|\))}
+dict set lexers H procRegexpCommand {regexp -nocase -all -line -- {^(?:(\w+)\s+)+(\*\w+|\w+)\s*\((.*?)(,|\))} $line match returns procName params v4}
+# dict set lexers C procRegexpCommand {regexp -nocase -all -- {\s*?func\s*?(\(\w+\s*?\**?\w+\)|)\s*?(\w+)\((.*?)\)\s+?([a-zA-Z0-9\{\}\[\]\(\)-_.]*?|)\s*?\{} $line match linkName procName params returns}
+dict set lexers C varRegexpCommand {regexp -nocase -all -line -- {^\s*(\w+\s+)+(?:[*\s]+)?(\w+)\s*[=;,\[]} $line match varType varName}
+dict set lexers H commands {auto break case const continue default do else enum extern for goto if inline  int long register restrict return signed sizeof static struct switch typedef typeof typeof_unqual union unsigned void volatile while}
+
 # -------------------------------------------------
 dict set lexers ALL varDirectory {variables vars group_vars host_vars defaults}

lib/menu.tcl

@@ -69,6 +69,15 @@ proc GetEditMenu {m} {
     -accelerator "Ctrl+F"
     # $m add command -label [::msgcat::mc "Replace"] -command Replace\
     # -accelerator "Ctrl+R"
+
+    $m add separator
+    menu $m.convertCase
+    $m add cascade -label [::msgcat::mc "Convert case"] -menu $m.convertCase
+    GetConvertCaseMenu $m.convertCase
+    menu $m.convertNamingStyle
+    $m add cascade -label [::msgcat::mc "Convert naming style"] -menu $m.convertNamingStyle
+    GetConvertIdentCaseMenu $m.convertNamingStyle
+
     $m add separator
     $m add command -label [::msgcat::mc "Find in files"] -command "FileOper::FindInFiles"\
     -accelerator "Ctrl+Shift+F"
@@ -138,3 +147,47 @@ proc GetHelpMenu {m} {
 proc PopupMenu {x y} {
     tk_popup .popup $x $y
 }
+
+# ============================================================
+# 2026 Vadim Ushakov <wandrien.dev@gmail.com>
+proc GetConvertCaseMenu {m} {
+    $m add command -label [::msgcat::mc "UPPER CASE"] -command SelectionToUpperCase\
+        -accelerator "Ctrl+Shift+U"
+    $m add command -label [::msgcat::mc "lower case"] -command SelectionToLowerCase\
+        -accelerator "Ctrl+Shift+L"
+    $m add command -label [::msgcat::mc "Title Case"] -command SelectionToTitleCase\
+        -accelerator "Ctrl+Shift+T"
+    $m add command -label [::msgcat::mc "Sentence case"] -command SelectionToSentenceCase\
+        -accelerator "Ctrl+Shift+Y"
+    $m add command -label [::msgcat::mc "iNVERT CASE"] -command SelectionToggleCase\
+        -accelerator "Ctrl+Shift+I"
+}
+proc GetConvertIdentCaseMenu {m} {
+    $m add command -label [::msgcat::mc "flatcase"] -command SelectionToFlatCase
+    $m add command -label [::msgcat::mc "UPPERCASE"] -command SelectionToUpperFlatCase
+
+    $m add separator
+
+    $m add command -label [::msgcat::mc "camelCase"] -command SelectionToCamelCase
+    $m add command -label [::msgcat::mc "PascalCase"] -command SelectionToPascalCase
+
+    $m add separator
+
+    $m add command -label [::msgcat::mc "snake_case"] -command SelectionToSnakeCase
+    $m add command -label [::msgcat::mc "SCREAMING_SNAKE_CASE"] -command SelectionToScreamingSnakeCase
+    $m add command -label [::msgcat::mc "camel_Snake_Case"] -command SelectionToCamelSnakeCase
+    $m add command -label [::msgcat::mc "Title_Case"] -command SelectionToTitleSnakeCase
+
+    $m add separator
+
+    $m add command -label [::msgcat::mc "kebab-case"] -command SelectionToKebabCase
+    $m add command -label [::msgcat::mc "SCREAMING-KEBAB-CASE"] -command SelectionToScreamingKebabCase
+    $m add command -label [::msgcat::mc "Train-Case"] -command SelectionToTrainCase
+
+    $m add separator
+
+    $m add command -label [::msgcat::mc "space separated"] -command SelectionToWords
+}
+# 2026 Vadim Ushakov <wandrien.dev@gmail.com>
+# ============================================================
+

lib/msgs/en.msg

@@ -185,4 +185,23 @@
 ::msgcat::mcset en "Word wrapping"
 ::msgcat::mcset en "Work dir"
 
+::msgcat::mcset en "Convert case"
+::msgcat::mcset en "Convert naming style"
+::msgcat::mcset en "UPPER CASE"
+::msgcat::mcset en "lower case"
+::msgcat::mcset en "Title Case"
+::msgcat::mcset en "Sentence case"
+::msgcat::mcset en "iNVERT CASE"
+::msgcat::mcset en "flatcase"
+::msgcat::mcset en "UPPERCASE"
+::msgcat::mcset en "camelCase"
+::msgcat::mcset en "PascalCase"
+::msgcat::mcset en "snake_case"
+::msgcat::mcset en "SCREAMING_SNAKE_CASE"
+::msgcat::mcset en "camel_Snake_Case"
+::msgcat::mcset en "Title_Case"
+::msgcat::mcset en "kebab-case"
+::msgcat::mcset en "SCREAMING-KEBAB-CASE"
+::msgcat::mcset en "Train-Case"
+::msgcat::mcset en "space separated"
 

lib/msgs/ru.msg

@@ -234,3 +234,23 @@
 ::msgcat::mcset ru "Editors word wrapping" "Перенос слов в редакторе"
 ::msgcat::mcset ru "Work dir" "Рабочий каталог"
 ::msgcat::mcset ru "Yes" "Да"
+
+::msgcat::mcset ru "Convert case" "Изменить регистр"
+::msgcat::mcset ru "Convert naming style" "Изменить стиль написания"
+::msgcat::mcset ru "UPPER CASE" "ЗАГЛАВНЫЕ БУКВЫ"
+::msgcat::mcset ru "lower case" "строчные буквы"
+::msgcat::mcset ru "Title Case" "С Заглавной Буквы"
+::msgcat::mcset ru "Sentence case" "Предложение с заглавной"
+::msgcat::mcset ru "iNVERT CASE" "иНВЕРТИРОВАННЫЙ РЕГИСТР"
+::msgcat::mcset ru "flatcase" "строчныебуквы"
+::msgcat::mcset ru "UPPERCASE" "ЗАГЛАВНЫЕБУКВЫ"
+::msgcat::mcset ru "camelCase" "camelCase"
+::msgcat::mcset ru "PascalCase" "PascalCase"
+::msgcat::mcset ru "snake_case" "строчные_буквы"
+::msgcat::mcset ru "SCREAMING_SNAKE_CASE" "ЗАГЛАВНЫЕ_БУКВЫ"
+::msgcat::mcset ru "camel_Snake_Case" "camel_Snake_Case"
+::msgcat::mcset ru "Title_Case" "С_Заглавной_Через_Подчеркивание"
+::msgcat::mcset ru "kebab-case" "строчные-буквы"
+::msgcat::mcset ru "SCREAMING-KEBAB-CASE" "ЗАГЛАВНЫЕ-БУКВЫ"
+::msgcat::mcset ru "Train-Case" "С-Заглавной-Через-Дефис"
+::msgcat::mcset ru "space separated" "разделить пробелом"

lib/procedure.tcl

@@ -1135,18 +1135,74 @@ proc ExecutorCommandPathSetting {fileType} {
     }
 }
 
-# -----------
-# Thanks https://github.com/wandrien/
+# =====================================================================
+# 2026 Vadim Ushakov <wandrien.dev@gmail.com>
 # https://github.com/wandrien/projman/commit/22f6e235c3532c20573d44ee7eaaaa1fb56ad544
-proc SendEventToLatestTxtWidget {ev} {
+proc ReplaceSelection {w newText} {
+    set selStart [$w index sel.first]
+
+    # Сохраняем и отключаем auto-separators
+    set autoSep [$w cget -autoseparators]
+    $w configure -autoseparators 0
+    
+    # Замена текста как атомарный блок в Undo-стеке
+    $w edit separator
+    $w delete sel.first sel.last
+    $w insert $selStart $newText
+    $w edit separator
+    
+    # Восстанавливаем autoseparators
+    $w configure -autoseparators $autoSep
+    
+    # Восстанавливаем выделение на новом тексте
+    set selEnd [$w index "$selStart + [string length $newText] chars"]
+    $w tag add sel $selStart $selEnd
+    
+    # Если ctext поддерживает подсветку - обновляем её
+    catch {$w highlight $selStart $selEnd}
+}
+
+proc HasSelection {w} {
+    set ranges [$w tag ranges sel]
+    return [expr {$ranges ne ""}]
+}
+
+proc GetLatestTxtWidget {} {
     global latestTxtWidget
     if {$latestTxtWidget eq ""} {
-        return
+        # pass
     } elseif {[winfo exists $latestTxtWidget] && [winfo class $latestTxtWidget] eq "Ctext"} {
-        event generate ${latestTxtWidget}.t $ev
+        # pass
     } else {
         set latestTxtWidget ""
     }
+    return $latestTxtWidget
+}
+
+proc ChoiceTxtWidgetOrLatest {{w ""}} {
+    if {$w ne ""} {
+        return $w
+    }
+    return [GetLatestTxtWidget]
+}
+
+proc ProcessSelection {handle {w ""}} {
+    set w [ChoiceTxtWidgetOrLatest $w]
+    if {$w eq ""} {
+        return
+    }
+    if {![HasSelection $w]} {
+        return
+    }
+    set text [$w get sel.first sel.last]
+    ReplaceSelection $w [$handle $text]
+}
+
+proc SendEventToLatestTxtWidget {ev} {
+    set w [GetLatestTxtWidget]
+    if {$w ne ""} {
+        event generate $w.t $ev
+    }
 }
 
 proc Cut {} { SendEventToLatestTxtWidget <<Cut>> }
@@ -1154,7 +1210,8 @@ proc Copy {} { SendEventToLatestTxtWidget <<Copy>> }
 proc Paste {} { SendEventToLatestTxtWidget <<Paste>> }
 proc Undo {} { SendEventToLatestTxtWidget <<Undo>> }
 proc Redo {} { SendEventToLatestTxtWidget <<Redo>> }
-# ------------
+# 2026 Vadim Ushakov <wandrien.dev@gmail.com>
+# =====================================================================
 
 proc DebugPuts {msg} {
     global cfgVariables

lib/text_case.tcl

@@ -0,0 +1,302 @@
+# Copyright 2026 Vadim Ushakov <wandrien.dev@gmail.com>
+
+proc SelectionToUpperCase {{w ""}} {
+    ProcessSelection TextToUpperCase $w
+}
+
+proc SelectionToLowerCase {{w ""}} {
+    ProcessSelection TextToLowerCase $w
+}
+
+proc SelectionToTitleCase {{w ""}} {
+    ProcessSelection TextToTitleCase $w
+}
+
+proc SelectionToggleCase {{w ""}} {
+    ProcessSelection TextToggleCase $w
+}
+
+proc SelectionToSentenceCase {{w ""}} {
+    ProcessSelection TextToSentenceCase $w
+}
+
+################################################################################
+
+proc TextToUpperCase {text} {
+    return [string toupper $text]
+}
+
+proc TextToLowerCase {text} {
+    return [string tolower $text]
+}
+
+proc TextToTitleCase {text} {
+    set result ""
+    set wordStart 1
+
+    foreach char [split $text ""] {
+        if {[string is alpha $char]} {
+            if {$wordStart} {
+                append result [string toupper $char]
+                set wordStart 0
+            } else {
+                append result [string tolower $char]
+            }
+        } else {
+            append result $char
+            if {[string is space $char] || $char in {- _ . , ; : ! ? ( ) [ ]}} {
+                set wordStart 1
+            }
+        }
+    }
+
+    return $result
+}
+
+proc TextToSentenceCase {text} {
+    set text [TextToLowerCase $text]
+    set result ""
+    set sentenceStart 1
+    set afterPunctuation 0
+
+    foreach char [split $text ""] {
+        if {[string is alpha $char]} {
+            if {$sentenceStart} {
+                append result [TextToUpperCase $char]
+                set sentenceStart 0
+            } else {
+                append result $char
+            }
+            set afterPunctuation 0
+        } elseif {$char in {. ! ?}} {
+            append result $char
+            set afterPunctuation 1
+        } elseif {[string is space $char]} {
+            append result $char
+            if {$afterPunctuation} {
+                set sentenceStart 1
+            }
+        } else {
+            append result $char
+            set afterPunctuation 0
+        }
+    }
+
+    return $result
+}
+
+proc TextToggleCase {text} {
+    set result ""
+
+    foreach char [split $text ""] {
+        if {[string is upper $char]} {
+            append result [TextToLowerCase $char]
+        } elseif {[string is lower $char]} {
+            append result [TextToUpperCase $char]
+        } else {
+            append result $char
+        }
+    }
+
+    return $result
+}
+
+################################################################################
+# Identifier case conversion
+################################################################################
+
+proc IsIdentSeparator {char} {
+    expr {$char eq "_" || $char eq "-" || [string is space $char]}
+}
+proc IsUpperChar {c} { string is upper -strict $c }
+proc IsLowerChar {c} { string is lower -strict $c }
+proc IsAlphaChar {c} { string is alpha -strict $c }
+proc IsDigitChar {c} { string is digit -strict $c }
+
+# Граница внутри "слитного" идентификатора (camel/pascal/акронимы/цифры):
+#  - lower -> Upper    : twoWords
+#  - digit <-> alpha   : word2Word, word2, 2word
+#  - "HTTPServer"      : HTTP | Server (между P и S, т.к. S Upper и дальше lower)
+proc IdentHasBoundary {prev cur next} {
+    set prevLower [IsLowerChar $prev]
+    set prevUpper [IsUpperChar $prev]
+    set prevAlpha [IsAlphaChar $prev]
+    set prevDigit [IsDigitChar $prev]
+
+    set curUpper  [IsUpperChar $cur]
+    set curAlpha  [IsAlphaChar $cur]
+    set curDigit  [IsDigitChar $cur]
+
+    set nextLower 0
+    if {$next ne ""} {
+        set nextLower [IsLowerChar $next]
+    }
+
+    if {$prevLower && $curUpper} {
+        return 1
+    }
+    if {($prevAlpha && $curDigit) || ($prevDigit && $curAlpha)} {
+        return 1
+    }
+    if {$prevUpper && $curUpper && $nextLower} {
+        return 1
+    }
+    return 0
+}
+
+# Главная стадия №1: распознать границы частей и вернуть список частей.
+proc IdentSplit {text} {
+    set parts {}
+    set token ""
+
+    set len [string length $text]
+    for {set i 0} {$i < $len} {incr i} {
+        set c [string index $text $i]
+
+        if {[IsIdentSeparator $c]} {
+            if {$token ne ""} {
+                lappend parts $token
+                set token ""
+            }
+            continue
+        }
+
+        if {$token ne ""} {
+            set prev [string index $text [expr {$i-1}]]
+            if {$i+1 < $len} {
+                set next [string index $text [expr {$i+1}]]
+            } else {
+                set next ""
+            }
+
+            if {[IdentHasBoundary $prev $c $next]} {
+                lappend parts $token
+                set token ""
+            }
+        }
+
+        append token $c
+    }
+
+    if {$token ne ""} {
+        lappend parts $token
+    }
+
+    return $parts
+}
+
+# Применение капитализации к одной части
+proc IdentPartLower {p} { string tolower $p }
+proc IdentPartUpper {p} { string toupper $p }
+proc IdentPartTitle {p} {
+    if {$p eq ""} { return "" }
+    set p [string tolower $p]
+    set first [string index $p 0]
+    set rest  [string range $p 1 end]
+    return "[string toupper $first]$rest"
+}
+
+proc IdentJoinAll {parts sep how} {
+    set out ""
+    set first 1
+    foreach p $parts {
+        if {!$first} { append out $sep } else { set first 0 }
+        switch -- $how {
+            lower { append out [IdentPartLower $p] }
+            upper { append out [IdentPartUpper $p] }
+            title { append out [IdentPartTitle $p] }
+            default { error "Unknown case '$how'" }
+        }
+    }
+    return $out
+}
+
+proc IdentJoinFirstRest {parts sep firstHow restHow} {
+    if {[llength $parts] == 0} { return "" }
+
+    set out ""
+    set i 0
+    foreach p $parts {
+        if {$i > 0} { append out $sep }
+        if {$i == 0} {
+            set how $firstHow
+        } else {
+            set how $restHow
+        }
+        switch -- $how {
+            lower { append out [IdentPartLower $p] }
+            upper { append out [IdentPartUpper $p] }
+            title { append out [IdentPartTitle $p] }
+            default { error "Unknown case '$how'" }
+        }
+        incr i
+    }
+    return $out
+}
+
+################################################################################
+# Stage №2: parts -> target representation
+################################################################################
+
+proc IdentToFlatCase {text} {
+    return [IdentJoinAll [IdentSplit $text] "" lower]   ;# twowords / flatcase
+}
+
+proc IdentToUpperFlatCase {text} {
+    return [IdentJoinAll [IdentSplit $text] "" upper]   ;# TWOWORDS / UPPERCASE
+}
+
+proc IdentToCamelCase {text} {
+    return [IdentJoinFirstRest [IdentSplit $text] "" lower title] ;# twoWords
+}
+
+proc IdentToPascalCase {text} {
+    return [IdentJoinAll [IdentSplit $text] "" title]   ;# TwoWords
+}
+
+proc IdentToSnakeCase {text} {
+    return [IdentJoinAll [IdentSplit $text] "_" lower]  ;# two_words
+}
+
+proc IdentToScreamingSnakeCase {text} {
+    return [IdentJoinAll [IdentSplit $text] "_" upper]  ;# TWO_WORDS
+}
+
+proc IdentToCamelSnakeCase {text} {
+    return [IdentJoinFirstRest [IdentSplit $text] "_" lower title] ;# two_Words
+}
+
+proc IdentToTitleSnakeCase {text} {
+    return [IdentJoinAll [IdentSplit $text] "_" title]  ;# Two_Words (Title_Case)
+}
+
+proc IdentToKebabCase {text} {
+    return [IdentJoinAll [IdentSplit $text] "-" lower]  ;# two-words
+}
+
+proc IdentToScreamingKebabCase {text} {
+    return [IdentJoinAll [IdentSplit $text] "-" upper]  ;# TWO-WORDS
+}
+
+proc IdentToTrainCase {text} {
+    return [IdentJoinAll [IdentSplit $text] "-" title]  ;# Two-Words
+}
+
+proc IdentToWords {text} {
+    return [IdentJoinAll [IdentSplit $text] " " lower]  ;# two words (space separated)
+}
+
+################################################################################
+
+proc SelectionToFlatCase {{w ""}}            { ProcessSelection IdentToFlatCase $w }
+proc SelectionToUpperFlatCase {{w ""}}       { ProcessSelection IdentToUpperFlatCase $w }
+proc SelectionToCamelCase {{w ""}}           { ProcessSelection IdentToCamelCase $w }
+proc SelectionToPascalCase {{w ""}}          { ProcessSelection IdentToPascalCase $w }
+proc SelectionToSnakeCase {{w ""}}           { ProcessSelection IdentToSnakeCase $w }
+proc SelectionToScreamingSnakeCase {{w ""}}  { ProcessSelection IdentToScreamingSnakeCase $w }
+proc SelectionToCamelSnakeCase {{w ""}}      { ProcessSelection IdentToCamelSnakeCase $w }
+proc SelectionToTitleSnakeCase {{w ""}}      { ProcessSelection IdentToTitleSnakeCase $w }
+proc SelectionToKebabCase {{w ""}}           { ProcessSelection IdentToKebabCase $w }
+proc SelectionToScreamingKebabCase {{w ""}}  { ProcessSelection IdentToScreamingKebabCase $w }
+proc SelectionToTrainCase {{w ""}}           { ProcessSelection IdentToTrainCase $w }
+proc SelectionToWords {{w ""}}               { ProcessSelection IdentToWords $w }

lib/tree.tcl

@@ -132,8 +132,10 @@ namespace eval Tree {
                 $nbEditor select $nbItem
                 set txt $nbItem.frmText.t
                 set findString [dict get $lexers [dict get $editors $txt fileType] procFindString]
+                DebugPuts "Tree::PressItem: $findString\n values: $values"
+                regsub -all {\*} $values {\\*} values
                 regsub -all {PROCNAME} $findString $values str
-
+                DebugPuts "Tree::PressItem: $str"
                 Editor::FindFunction $txt "$str"
             }
         }

projman.tcl

@@ -9,8 +9,8 @@ exec wish8.6 "$0" -- "$@"
 # Home page: https://nuk-svk.ru
 ######################################################
 # Version: 2.0.0
-# Release: beta3
-# Build: 06022026135717
+# Release: beta5
+# Build: 17022026124216
 ######################################################
 
 # определим текущую версию, релиз и т.д.

redhat/projman.spec

@@ -70,6 +70,22 @@ fi
 %{_iconsdir}/hicolor/48x48/apps/projman.png
 
 %changelog
+* Tue Feb 17 2026 Sergey Kalinin <svkalinin@samsonpost.ru> 2.0.0-beta5
+    -  Добавил код из https://github.com/wandrien/projman/tree/master для работы с выделенным текстом. И внес изменения в связи с этим.
+    -  Исправления работы с С
+
+* Fri Feb 13 2026 svk <svk@nuk-svk.ru> 2.0.0-beta4
+    -  Исправлено регулярное выражение для поиска переменных в коде на С.
+    -  Добавил экранирование '*' в имени функции для поиска.
+    -  Подкрректировал регулярки для работы с С.
+    -  Исправил закрытие вкладки при отпускании кнопки мыши при нажатии на крестик.
+    -  Добавил иконки для 'c' и 'h'. Добавил сочитание Alt-R в русской раскладке
+    -  Добавил поддержку С (подсветка)
+    -  Добавил копирование готовых пакетов
+
+* Fri Feb  6 2026 svk <svk@nuk-svk.ru> 2.0.0-beta3
+    -  Откорректировал сборку рпм
+
 * Fri Feb  6 2026 svk <svk@nuk-svk.ru> 2.0.0-beta3
     -  Добавил сборку rpm. Исправил changelog-и
 
@@ -225,3 +241,5 @@ fi
 
 
 
+
+